Unicode true
RequestExecutionLevel user
SetCompressor /SOLID lzma

!ifndef APP_VERSION
  !error "APP_VERSION is required"
!endif
!ifndef STAGE_DIR
  !error "STAGE_DIR is required"
!endif
!ifndef OUTPUT_FILE
  !error "OUTPUT_FILE is required"
!endif

Name "HoloLake Era"
OutFile "${OUTPUT_FILE}"
InstallDir "$LOCALAPPDATA\Programs\HoloLake Era"
InstallDirRegKey HKCU "Software\Guanghu\HoloLake Era" "InstallDir"
Icon "${STAGE_DIR}/icon.ico"
UninstallIcon "${STAGE_DIR}/icon.ico"

VIProductVersion "${APP_VERSION}.0"
VIAddVersionKey "ProductName" "HoloLake Era"
VIAddVersionKey "ProductVersion" "${APP_VERSION}"
VIAddVersionKey "FileVersion" "${APP_VERSION}"
VIAddVersionKey "CompanyName" "Guanghu Language World"
VIAddVersionKey "FileDescription" "HoloLake Era internal installer"
VIAddVersionKey "LegalCopyright" "Guanghu Language World"

Page directory
Page instfiles
UninstPage uninstConfirm
UninstPage instfiles

Section "HoloLake Era" SEC_MAIN
  SetOutPath "$INSTDIR"
  File "${STAGE_DIR}/HoloLake Era.exe"
  File "${STAGE_DIR}/icon.ico"
  File /r "${STAGE_DIR}/resources"

  WriteUninstaller "$INSTDIR\Uninstall.exe"
  WriteRegStr HKCU "Software\Guanghu\HoloLake Era" "InstallDir" "$INSTDIR"
  WriteRegStr HKCU "Software\Microsoft\Windows\CurrentVersion\Uninstall\HoloLakeEra" "DisplayName" "HoloLake Era"
  WriteRegStr HKCU "Software\Microsoft\Windows\CurrentVersion\Uninstall\HoloLakeEra" "DisplayVersion" "${APP_VERSION}"
  WriteRegStr HKCU "Software\Microsoft\Windows\CurrentVersion\Uninstall\HoloLakeEra" "DisplayIcon" "$INSTDIR\icon.ico"
  WriteRegStr HKCU "Software\Microsoft\Windows\CurrentVersion\Uninstall\HoloLakeEra" "UninstallString" '"$INSTDIR\Uninstall.exe"'

  CreateDirectory "$SMPROGRAMS\HoloLake Era"
  CreateShortcut "$SMPROGRAMS\HoloLake Era\HoloLake Era.lnk" "$INSTDIR\HoloLake Era.exe" "" "$INSTDIR\icon.ico"
  CreateShortcut "$DESKTOP\HoloLake Era.lnk" "$INSTDIR\HoloLake Era.exe" "" "$INSTDIR\icon.ico"

  WriteRegStr HKCU "Software\Classes\tolaria" "" "URL:Tolaria Protocol"
  WriteRegStr HKCU "Software\Classes\tolaria" "URL Protocol" ""
  WriteRegStr HKCU "Software\Classes\tolaria\shell\open\command" "" '"$INSTDIR\HoloLake Era.exe" "%1"'
  WriteRegStr HKCU "Software\Classes\guanghu" "" "URL:Guanghu Protocol"
  WriteRegStr HKCU "Software\Classes\guanghu" "URL Protocol" ""
  WriteRegStr HKCU "Software\Classes\guanghu\shell\open\command" "" '"$INSTDIR\HoloLake Era.exe" "%1"'
SectionEnd

Section "Uninstall"
  Delete "$DESKTOP\HoloLake Era.lnk"
  RMDir /r "$SMPROGRAMS\HoloLake Era"
  DeleteRegKey HKCU "Software\Classes\tolaria"
  DeleteRegKey HKCU "Software\Classes\guanghu"
  DeleteRegKey HKCU "Software\Microsoft\Windows\CurrentVersion\Uninstall\HoloLakeEra"
  DeleteRegKey HKCU "Software\Guanghu\HoloLake Era"
  RMDir /r "$INSTDIR"
SectionEnd